The Jack's Files

Public Class ViewStateAdapter
    Inherits System.Web.UI.Adapters.PageAdapter '繼承 System.Web.UI.Adapters.PageAdapter

    Public Overrides Function GetStatePersister() As System.Web.UI.PageStatePersister
        '如果你要存在Session裡，寫這一句就行了，這是微軟內建的
        'Return New System.Web.UI.SessionPageStatePersister(Me.Page)

        '不過我們今天要自己寫個Persister，存到硬碟裡
        Return New ViewStatePersister(Me.Page)

    End Function
End Class

    

Public Class ViewStatePersister
    Inherits System.Web.UI.PageStatePersister

    'viewstate檔案存在這個路徑下
    Private Const _strFilePathFormat As String = "~/PersistedViewState/{0}.vs.resource"

    '使用Guid編一個唯一的viewstate檔案名稱
    Private _strNewGuid As String = Guid.NewGuid().ToString()

    '這是網頁上一個HiddenField的欄位名稱，viewstate的檔案名稱會保存在這裡
    Private Const _strViewStateHiddenFieldName As String = "__ViewStateGuid"

    Public Sub New(ByVal p As System.Web.UI.Page)
        MyBase.New(p)
    End Sub

    ''' <summary>
    ''' 重寫 Load 方法，從Server的硬碟裡讀取 ViewState
    ''' </summary>
    Public Overrides Sub Load()

        Dim strViewStateFilePath As String = Me.Page.Server.MapPath(String.Format(_strFilePathFormat, Me.Page.Request.Form(_strViewStateHiddenFieldName)))
        ' deserialize the base-64 encoded string into a view state
        If Not IO.File.Exists(strViewStateFilePath) Then
            Throw New Exception("保存 Viewstate 的文件 \" & strViewStateFilePath & " \ 不存在")
        Else
            ' instantiates the formatter and opens the file
            Dim objLosFormatter As LosFormatter = New LosFormatter()
            Dim objStreamReader As IO.StreamReader = IO.File.OpenText(strViewStateFilePath)
            Dim strViewState As String = objStreamReader.ReadToEnd()
            objStreamReader.Close()

            Dim statePair As Pair = CType(objLosFormatter.Deserialize(strViewState), Pair)
            ViewState = statePair.First
            ControlState = statePair.Second
        End If

    End Sub

    ''' <summary>
    ''' 重寫 Save 方法，保存 ViewState 到Server的硬碟裡
    ''' </summary>
    Public Overrides Sub Save()
        ' serialize the view state into a base-64 encoded string
        Dim objLosFormatter As LosFormatter = New LosFormatter()
        Using objStringWriter As IO.StringWriter = New IO.StringWriter()
            ' save the view state to disk
            Dim statePair As Pair = New Pair(ViewState, ControlState)
            objLosFormatter.Serialize(objStringWriter, statePair)
            WirteViewStateToFile(objStringWriter)
        End Using
        ' saves the view state GUID to a hidden field
        Page.ClientScript.RegisterHiddenField(_strViewStateHiddenFieldName, _strNewGuid)

    End Sub

    ''' <summary>
    ''' 存檔的實際邏輯
    ''' </summary>
    Private Sub WirteViewStateToFile(ByVal SW As IO.StringWriter)
        If Not Me.Page.Request.Form(_strViewStateHiddenFieldName) Is Nothing Then
            _strNewGuid = Me.Page.Request.Form(_strViewStateHiddenFieldName)
        End If

        Dim strViewStateFilePath As String = Me.Page.Server.MapPath(String.Format(_strFilePathFormat, _strNewGuid))
        Try
            Using objStreamWriter As IO.StreamWriter = IO.File.CreateText(strViewStateFilePath)
                objStreamWriter.Write(SW.ToString())
            End Using

        Catch dnfEx As IO.DirectoryNotFoundException
            IO.Directory.CreateDirectory(strViewStateFilePath.Substring(0, strViewStateFilePath.LastIndexOf("\")))
            WirteViewStateToFile(SW)
        End Try

    End Sub

End Class